***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 30, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PZS515V1BCH-AU A K
.param
+vc0 = 4.046e-13	 vc1 = 5.053e-11	 vc2 = 1.000		 vc3 = 2.651e-12		 vc4 = 3.325
+tc1 = 3.501e-2		 tc2 = 1.147e-2		 tc3 = 4.941e-3		 tc4 = 1.721e-3	
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 3.542e-16	   n = 1.000		  rs = 1.365e-1		 ikf = 25.67
+ibv = 50e-6		 nbv = 1.5		  bv = 5.1
***** capacitance parameter ***
+cjo = 1.073e-10	   m = 3.236e-1		  vj = 6.791e-1
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25		  eg = 1.122		 xti = 3
+trs1 = 1.066e-3	trs2 = -3.006e-6	tbv1 = 1.172e-4		tbv2 = -5.5e-7
.ends PZS515V1BCH-AU
*$
